staging.inyokaproject.org

#!/usr/bin/perl -w
# Copyright (C) 2010  Dominik Burgdörfer

# MakeBranchDist 0.1.2 -- This program creates a distribution
#                         based on a bzr-branch. It also searches
#                         for headers in files in the following form:
#                           # $Id$
#                           // $Id$
#
#                         These headers replaced by RCS-like Id-fields.

# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

use strict;
use File::Basename;
use File::Path qw(make_path remove_tree);
use File::Copy;

# Functions to handle bazaar-vcs
package Bzr;

# Returns a hash with info about the
# branch in the current directory.
sub version_info {
    my $bzr = defined($_[0]) ? $_[0] : "bzr";

    my $info_hash = {};

    my $bzr_cmd = "'$bzr' version-info --custom ".
        "--template ".
        "'my \$info_hash = {}; \$info_hash->{\"date\"}='\\''{date}'\\'';".
        "\$info_hash->{\"build_date\"}='\\''{build_date}'\\'';".
        "\$info_hash->{\"revno\"}={revno};".
        "\$info_hash->{\"revision_id\"}='\\''{revision_id}'\\'';".
        "\$info_hash->{\"branch_nick\"}='\\''{branch_nick}'\\'';".
        "\$info_hash->{\"clean\"}={clean};\$info_hash;'";

    # Evaluate the output of bazaar.
    $info_hash = eval(`$bzr_cmd`);
    die($@) if(!$info_hash);

    # Return the hash
    $info_hash;
}

# Returns an array of all versioned files in
# the current directory.
# TODO: Probably not the best solution to pack
#       all files in one big array. Should be
#       replaced with a file-descriptor.
sub versioned_files {
    open(BZR_HANDLE, "bzr ls --versioned -R |") ||
        warn("unable to launch bzr");

    if(wantarray) {
        return <BZR_HANDLE>;
    }
    else {
        return scalar(<BZR_HANDLE>);
    }
}


package main;

my $version_info;
my @versioned_files;

# Retrieve information about the current branch
if(-d ".bzr") {
    $version_info = Bzr::version_info();
    @versioned_files = Bzr::versioned_files();
}
elsif(-d ".svn") {
    die("svn is not yet implemented");
}
else {
    die("could not determine used version-control system.");
}

# Little goodie :-D. Check if the tree has
# uncommitted changes. Maybe useless but looks
# cool :-D
if(!$version_info->{clean}) {
    print STDERR "tree has uncommitted changes.\n";
}

# Create release-directory.
my $release_dir = $version_info->{branch_nick}."-r".
    $version_info->{revno};

-d $release_dir && remove_tree($release_dir);

make_path($release_dir);


# Iterate through all versioned files, to eventually
# edit them and copy to the release-directory.
for(@versioned_files) {
    chomp;
    
    if(-f) {
        open(FILE, "<", $_) || die("unable to read $_: $!");

        my $new_path = $release_dir."/".$_;
        make_path(dirname($new_path));

        my $firstLine = <FILE>;
        chomp($firstLine);

        # Check if first line is an id-comment-line.
        # If so replace it with information about the branch.
        if($firstLine =~ /^([ \t]*(#|\/\/)[ \t]*)\$Id\$[ \t]*$/) {
            open(NEW_FILE, ">", $new_path) ||
                die("unable to create $new_path: $!");

            printf NEW_FILE "$1\$Id: %s %d %s \$\n", basename($_),
                                                     $version_info->{revno},
                                                     $version_info->{build_date};

            while(<FILE>) {
                print NEW_FILE $_;
            }
            
            close(NEW_FILE);
        }
        else {
            # No modifications to do, just copy the file to
            # the release-directory.
            copy($_, $release_dir."/".dirname($_));
        }
    }
}