staging.inyokaproject.org

#!/usr/bin/env coffee
'use strict'
_ = require 'lodash'
fs = require 'fs'
path = require 'path'


class SameFiles
  
  constructor: (@inode) -> @items = []

  add: (file) -> @items.push file; @

  getCount: -> @items.length
  
  getLinkCount: -> _.last(@items)?.linkCount ? 0
  
  hasConsistentLinkCount: ->
    expected = @getLinkCount()
    @items.every (file) -> file.linkCount == expected
  
  hasMoreLinksThanFound: -> @getCount() < @getLinkCount()


class FileCollector
  
  constructor: (@deviceID) ->
    @inode2files = {}
  
  isPathOnDevice: (path) ->
    stats = fs.lstatSync path
    stats.dev == @deviceID
  
  add: (stats, filename) ->
    inode = stats.ino
    files = @inode2files[inode] ?= new SameFiles inode
    files.add {linkCount: stats.nlink, name: filename}
    @
  
  read: (basePath) ->
    try
      if @isPathOnDevice basePath
        for name in fs.readdirSync basePath
          subPath = path.join basePath, name
          stats = fs.lstatSync subPath
          if stats.isDirectory()
            @read subPath
          else if stats.isFile() or stats.isSymbolicLink()
            @add stats, subPath
    catch error
      if error.errno? and error.message?
        console.error error.message
      else
        throw error
    
  getSameFiles: ->
    files for inode, files of @inode2files \
      when files.getCount() > 1 or files.hasMoreLinksThanFound()


getSameFiles = (basePath) ->
  baseStats =
    try
      fs.lstatSync basePath
    catch error
      if error.errno? and error.message?
        console.error error.message
        null
      else
        throw error
    
  if baseStats isnt null
    fileCollector = new FileCollector baseStats.dev
    fileCollector.read basePath
    fileCollector.getSameFiles()


main = ->
  if process.argv.length < 3
    console.error "Usage: #{process.argv[1]} base_path"
  else
    basePath = process.argv[2]
    for sameFiles in _.sortBy(getSameFiles(basePath), 'inode')
      unless sameFiles.hasConsistentLinkCount()
        warning = ' links where created/deleted while collecting infos'
      else if sameFiles.hasMoreLinksThanFound()
        diff = sameFiles.getLinkCount() - sameFiles.getCount()
        warning = " has #{diff} more link(s) from somewhere else"
      else
        warning = ''
    
      console.log "inode: #{sameFiles.inode}" + warning
      
      for file in _.sortBy(sameFiles.items, 'name')
        console.log "  #{file.linkCount} #{file.name}"
  null


main() if require.main == module